Results 1 to 6 of 6
  1. #1
    3 Star Lounger
    Join Date
    Jan 2003
    Location
    Den Haag, Netherlands
    Posts
    208
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Cool

    Good morning!

    Okay, I've a question I don't quiet understand myself, so let me try to explain

    A couple of users want to have their e-mail forwarded and flagged (at the same time) to another e-mailaddress with one push at a button (a macro I suppose?).
    Is this possible at all?

    I know about wizard rules, but they specifically asked for a button underneath the titlebar. (welcome to my user-world).

    I hope somebody can help me with this. (I've tried to do something with VBA, but that's not my 'thing' ).

    Many thanks in advance!

    Daphne

  2. #2
    Plutonium Lounger
    Join Date
    Mar 2002
    Posts
    84,353
    Thanks
    0
    Thanked 29 Times in 29 Posts
    [quote name='drietveld' post='764318' date='09-Mar-2009 11:23'][/quote]
    Do they want to forward to a fixed e-mail address?
    How exactly should the message be flagged?

  3. #3
    3 Star Lounger
    Join Date
    Jan 2003
    Location
    Den Haag, Netherlands
    Posts
    208
    Thanks
    0
    Thanked 0 Times in 0 Posts
    The e-mail has to be addressed to a fixed other mailaddress.
    These e-mails have to be selected and send seperately to this mailaddress (I know I can select e-mails and forward them at once, but then the receiver receives one e-mail with the e-mailmessages as attachments, and they don't want that).
    Then... (nope, I'm not ready) these mails have to be flagged (so the person can see that this e-mail was sent) and NOT be saved again in the sent items.

    Can you still follow me?

    Greetz,
    Daphne

  4. #4
    Plutonium Lounger
    Join Date
    Mar 2002
    Posts
    84,353
    Thanks
    0
    Thanked 29 Times in 29 Posts
    [quote name='drietveld' post='764345' date='09-Mar-2009 14:02'][/quote]
    When an e-mail is forwarded, Outlook will display a blue arrow in the e-mail's icon.

    You could use a macro like the following and assign it to a custom toolbar button:
    Code:
    Sub ForwardSelected()
      Dim strMsg As String
      Dim itm As MailItem
      Dim itmF As MailItem
      On Error GoTo ErrHandler
    
      If TypeName(ActiveWindow) = "Inspector" Then
    	Set itm = ActiveInspector.CurrentItem
    	If Not itm.Class = olMail Then
    	  strMsg = "This item is not an e-mail message."
    	Else
    	End If
      ElseIf TypeName(ActiveWindow) = "Explorer" Then
    	If ActiveExplorer.CurrentFolder.Items.Count = 0 Then
    	  strMsg = "This folder doesn't contain any items."
    	ElseIf Not ActiveExplorer.Selection.Count = 1 Then
    	  strMsg = "Please select only one item."
    	Else
    	  Set itm = ActiveExplorer.Selection.Item(1)
    	End If
      End If
    
      If strMsg = "" Then
    	Set itmF = itm.Forward
    	' Change the e-mail address to that of the intended recipient
    	itmF.Recipients.Add "john.doe@company.com"
    	itmF.Send
      Else
    	MsgBox strMsg, vbExclamation
      End If
      Exit Sub
    
    ErrHandler:
      MsgBox Err.Description, vbExclamation
    End Sub

  5. #5
    3 Star Lounger
    Join Date
    Jan 2003
    Location
    Den Haag, Netherlands
    Posts
    208
    Thanks
    0
    Thanked 0 Times in 0 Posts
    Phew!!! I'm gonna try this!!! Thanks!!!!

  6. #6
    5 Star Lounger
    Join Date
    May 2001
    Location
    Patterson Lakes, Melbourne, Victoria, Australia
    Posts
    637
    Thanks
    0
    Thanked 0 Times in 0 Posts
    Daphne, I had a similar need. I overcame it (with Han's help) by using a button on Outlooks menu. The button caused a copy of the email and attachments to be sent to my secretary. Teh instructions and code ae below.

    Forward To Secretary Button Code in Outlook

    Put code into Outlook
    Put this in a standard module. To create a module if one isn’t there: right-click the Project and Inserting a new Module. Paste the code below into this module.
    Attach code to Toolbar button.
    In ‘Customize’ mode, select Macros and drag the macro to the Toolbar.
    Then right click on the Toolbar item and select ‘Default Style’. This is the style for an icon only. Go to D:\Updates&Programs\icons. Open ‘Forward2Sec’ in say IrfanView, copy it. Back to Outlook (still in ‘Customize’ mode), right click on the new icon an select ‘Paste Button Image’

    [codebox]Sub Forward2Secretary()
    Const strSecretary = "susan@lakeedge.biz"
    Dim lngC As Long
    Dim strMsg As String
    On Error GoTo ErrHandler
    If TypeName(ActiveWindow) = "Inspector" Then
    If Not ActiveInspector.CurrentItem.Class = olMail Then
    strMsg = "This item is not an e-mail message."
    Else
    With ActiveInspector.CurrentItem.Forward
    .Recipients.Add strSecretary
    .Send
    Beep
    End With
    End If
    ElseIf TypeName(ActiveWindow) = "Explorer" Then
    If ActiveExplorer.CurrentFolder.Items.Count > 0 Then
    If ActiveExplorer.Selection.Count > 0 Then
    For lngC = 1 To ActiveExplorer.Selection.Count
    If ActiveExplorer.Selection.Item(lngC).Class = olMail Then
    With ActiveExplorer.Selection.Item(lngC).Forward
    .Recipients.Add strSecretary
    .Send
    Beep
    End With
    End If
    Next lngC
    Exit Sub
    Else
    strMsg = "You haven't selected any items."
    End If
    Else
    strMsg = "This folder doesn't contain any items."
    End If
    End If

    If Not strMsg = "" Then
    MsgBox strMsg, vbExclamation
    End If
    Exit Sub

    ErrHandler:
    MsgBox Err.Description, vbExclamation
    End Sub
    [/codebox]
    Regards,
    Peter

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •