Results 1 to 3 of 3
  1. #1
    2 Star Lounger
    Join Date
    Mar 2001
    Posts
    165
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Separate footnotes from document (Word 97 SR-2)

    I want to separate the footnotes from a Word document to place them manually into a PageMaker document. If I just copy the notes and paste them into a new Word document, the note numbers all come up as "1". Is there a way I can make a new Word document with just the footnotes, while preserving the footnote numbers?
    Clark

  2. #2
    Super Moderator jscher2000's Avatar
    Join Date
    Feb 2001
    Location
    Silicon Valley, USA
    Posts
    23,112
    Thanks
    5
    Thanked 93 Times in 89 Posts

    Re: Separate footnotes from document (Word 97 SR-2)

    Clark, I'm with you, man. Since the last version of this procedure already had the text in the clipboard, it wasn't too many more steps to stuff it into a new document. The hardest part is remembering to work backwards.

    <pre>Sub SeparateFootnotes()
    If MsgBox("Move footnotes to a new document, leaving note numbers only?", _
    vbQuestion + vbYesNo) <> vbYes Then Exit Sub

    ' create a second doc for the notes
    Dim docOriginal As Document, docNew As Document
    Set docOriginal = ActiveDocument
    Set docNew = Documents.Add

    ' loop through footnotes moving the note text to the new doc
    ' and replacing the note reference with a number
    Dim intCounter As Integer, rngMyRange As Range, rngTempRange As Range
    For intCounter = docOriginal.Footnotes.Count To 1 Step -1
    'copy footnote contents the clipboard
    docOriginal.Footnotes(intCounter).Range.Select
    Selection.Copy
    'clear footnote number and replace with superscripted counter
    Set rngMyRange = docOriginal.Footnotes(intCounter).Reference
    rngMyRange.Select
    With Selection
    .Delete
    .Font.Superscript = True
    .TypeText intCounter
    End With
    'paste note text into docNew
    Set rngTempRange = docNew.Range
    With rngTempRange
    .Collapse wdCollapseStart
    .Paste
    .InsertBefore intCounter & "." & vbTab
    .InsertParagraphBefore
    End With
    Next
    docNew.Range.InsertBefore "Footnotes for " & docOriginal.FullName
    Set rngTempRange = Nothing
    Set rngMyRange = Nothing
    Set docNew = Nothing
    Set docOriginal = Nothing
    End Sub</pre>

    Let me know if this does what you need.

  3. #3
    2 Star Lounger
    Join Date
    Mar 2001
    Posts
    165
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Re: Separate footnotes from document (Word 97 SR-2)

    That fixed it. Thanks very much! I knew I could count on you. Give me your address and I'll send you a free copy of the book when it's finished.
    Clark

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •