Declare a public variable while updating systems

[maverik]

Hi, I hope someone can help me. I'm not sure if this can even be done, but we are in the process of upgrading all the systems in our office to Word 2010 and Windows 7. In the meantime, we have some systems running on Windows 7 and Word 2003 and some on Windows XP and Word 2003. The paths to the Startup folders where the Addins are stored are different in that the Windows 7 machines are referencing c:\program files (x86)\Microsoft Office\Office 11\Startup. I have a string publically declared that references Public Const STRSTARTUPPATH As String = "C:\Program Files\Microsoft Office\Office11\Startup\"

Is there a way that I can somehow check to see if the system is on Windows 7 or Windows XP and then adjust the path on this string accordingly?

Thanks so much.

[RetiredGeek]

Maverick,

Here's code to determing the Windows Version.

Option Explicit

Type OSVERSIONINFO   '  148 Bytes
        dwOSVersionInfoSize As Long
        dwMajorVersion As Long
        dwMinorVersion As Long
        dwBuildNumber As Long
        dwPlatformId As Long
        szCSDVersion As String * 128
End Type

Declare Function GetVersionEx& Lib "kernel32" _
Alias "GetVersionExA" (lpVersionInformation As OSVERSIONINFO)

'                        +----------------------+                +----------+
'------------------------| FindWindowsVersion() |----------------| 07/15/10 |
'                        +----------------------+                +----------+

Sub FindWindowsVersion()

   Dim tOSVer As OSVERSIONINFO
   Dim bNT    As Boolean    '*** Is this a version of NT? ***
   Dim zOsVer As String
   
   bNT = IIf(InStr(Application.OperatingSystem, "NT") = 0, False, True)
   
   tOSVer.dwOSVersionInfoSize = 148
   GetVersionEx& tOSVer
   
   With tOSVer
   
       If bNT Then
         Select Case .dwMajorVersion
             Case 4: zOsVer = "Windows NT4"
             Case 5: zOsVer = _
                  IIf(.dwMinorVersion = 1, "Windows XP", "Windows 2000")
             Case 6: zOsVer = "Windows 7"
         End Select
         
       Else
       
         Select Case .dwMajorVersion
             Case 4:
                 Select Case .dwMinorVersion
                       Case 0: zOsVer = "Windows 95"
                       Case 1: zOsVer = "Windows 98"
                       Case 9: zOsVer = "Windows ME"
                 End Select
             Case 5: zOsVer = _
                  IIf(.dwMinorVersion = 1, "Windows XP", "Windows 2000")
         End Select
         
       End If
       
   End With      'tOSVer
   
   MsgBox "OS Version: " & zOsVer, vbOKOnly + vbInformation, _
          "Operating System Version"
          
End Sub                  'FindWindowsVersion

[macropod]

On a PC with Office 2010, your startup path wouldn't be referencing a folder named 'Office 11' - which is for Word 2003. Accordingly, you're going to need something more sophisticated. Perhaps you could tell us what kinds of Addins you're concerned with and the context in which you're trying to retrieve their path.

[Andrew Lockton]

If you already have Word open then one line might be adequate.
Application.StartupPath

But as macropod asks, perhaps there is something trickier you are trying to do with your addins.

[maverik]

Thank you so much. I tried using the coding for determining which version of Windows, but couldn't get it to save to a public variable. So thanks so much for the Application.StartupPath tip -- I had to replace that in all the macros themselves, but that was a simple search and replace.

Everything is resolved now. Thanks again.