Results 1 to 4 of 4
  1. #1
    3 Star Lounger
    Join Date
    Dec 2003
    Location
    Perth, Western Australia, Australia
    Posts
    393
    Thanks
    15
    Thanked 0 Times in 0 Posts

    Help with iserror in array

    Hi Loungers, I have the array formula below (1) and trying to include the iserror function (2) to remove #N/A's etc. but keep getting error messages.

    (1)
    {=INDEX('EOM Export Import'!$Z$10:$Z$457,MATCH(1,IF('EOM Export Import'!$C$10:$C$457='Lead indicators'!$C7,IF('EOM Export Import'!$B$10:$B$457='Lead indicators'!D$6,1)),0))}

    (2)
    {=if(iserror(INDEX('EOM Export Import'!$Z$10:$Z$457,MATCH(1,IF('EOM Export Import'!$C$10:$C$457='Lead indicators'!$C7,IF('EOM Export Import'!$B$10:$B$457='Lead indicators'!D$6,1)),0)),"0",(INDEX('EOM Export Import'!$Z$10:$Z$457,MATCH(1,IF('EOM Export Import'!$C$10:$C$457='Lead indicators'!$C7,IF('EOM Export Import'!$B$10:$B$457='Lead indicators'!D$6,1)),0))}

    Any thoughts/suggests would be appreciated.

    Regards

  2. #2
    WS Lounge VIP sdckapr's Avatar
    Join Date
    Jul 2002
    Location
    Pittsburgh, Pennsylvania, USA
    Posts
    11,225
    Thanks
    14
    Thanked 341 Times in 334 Posts
    Your formula is missing a closing parenthesis:
    =IF(ISERROR(INDEX('EOM Export Import'!$Z$10:$Z$457,MATCH(1,IF('EOM Export Import'!$C$10:$C$457='Lead indicators'!$C7,IF('EOM Export Import'!$B$10:$B$457='Lead indicators'!D$6,1)),0))),"0",(INDEX('EOM Export Import'!$Z$10:$Z$457,MATCH(1,IF('EOM Export Import'!$C$10:$C$457='Lead indicators'!$C7,IF('EOM Export Import'!$B$10:$B$457='Lead indicators'!D$6,1)),0))

    Note if you have XL2007 or later, you can just use the IFERROR function to not repeat the formula:
    =IFERROR(INDEX('EOM Export Import'!$Z$10:$Z$457,MATCH(1,IF('EOM Export Import'!$C$10:$C$457='Lead indicators'!$C7,IF('EOM Export Import'!$B$10:$B$457='Lead indicators'!D$6,1)),0)),"0")

    Steve

  3. #3
    3 Star Lounger
    Join Date
    Dec 2003
    Location
    Perth, Western Australia, Australia
    Posts
    393
    Thanks
    15
    Thanked 0 Times in 0 Posts
    Thanks very much for your help. I know it was close, just missed that parenthesis.

    Looks like the IFERROR function will be better.

    Regards

  4. #4
    WS Lounge VIP sdckapr's Avatar
    Join Date
    Jul 2002
    Location
    Pittsburgh, Pennsylvania, USA
    Posts
    11,225
    Thanks
    14
    Thanked 341 Times in 334 Posts
    IFERROR IMO is one of the better functions added. In the past XL versions we needed a redundant clause, repeating the entire formula:
    =IF(ISERROR(MyFormula), "" , MyFormula)

    Essentially, if my formula results in a error, mask the error with a null string, otherwise use my formula. But my formula is in it twice.
    With the IFERROR you do not need to add the formula twice:
    =IFERROR(MyFormula, "")

    Essentially, use my formula unless it has an error then use a null.

    Steve

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •