Results 1 to 4 of 4
  1. #1
    New Lounger
    Join Date
    Sep 2015
    Posts
    10
    Thanks
    1
    Thanked 0 Times in 0 Posts

    Find docs with tracked changes

    I'm wondering if it is possible to search a Windows directory (Windows 7 enterprise) to find all Word documents that contain tracked changes or comments. I've tried my friend Google, but I get about 4 million hits about using tracked changes in Word.
    In a multi-layered file structure, as editors we use tracked changes and comments to send back to the author for actioning. Once the issue is resolved, the changes are accepted and the files are sent onto the next process. If we make a comment in a document, the filename is changed to indicate it; when we clear the changes, the filename is changed again. But every now and then, the changes are missed and the filename is not 100% reliable as it depends on users being 100% brilliant 100% of the time.
    At the moment, to double check everything has been actioned we have two choices: work our way through every document in every sub-directory, or (as I do) import all documents in the directory to a single Word document, troll through for tracked changes, and open the original file whenever there's a stray one that's been missed. Both a pretty inefficient.
    I'd love to be able to go to Explorer and type something like "trackedchanges:yes" and have any document in the directory with tracked changes in my list. Am I dreaming to big?

  2. #2
    Administrator
    Join Date
    Mar 2001
    Location
    St Louis, Missouri, USA
    Posts
    23,594
    Thanks
    5
    Thanked 1,059 Times in 928 Posts
    It is unlikely you can do this with Explorer as tracked changes are a Word function and not a document property that I know. I'm moving this to the Word forum. Perhaps someone there has an answer.

    Joe

  3. #3
    New Lounger
    Join Date
    Sep 2015
    Posts
    10
    Thanks
    1
    Thanked 0 Times in 0 Posts
    Thank you.

  4. #4
    Super Moderator
    Join Date
    May 2002
    Location
    Canberra, Australian Capital Territory, Australia
    Posts
    5,055
    Thanks
    2
    Thanked 417 Times in 346 Posts
    If you create a 'Revisions Report' document, you could run a macro like:
    Code:
    Sub RevisionsReport()
    Application.ScreenUpdating = False
    Dim strFolder As String, strFile As String, strDocNm As String, strReport As String, wdDoc As Document
    strDocNm = ThisDocument.FullName
    strFolder = GetFolder
    If strFolder = "" Then Exit Sub
    strFile = Dir(strFolder & "\*.doc", vbNormal)
    While strFile <> ""
      If strFolder & "\" & strFile <> strDocNm Then
        Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
        With wdDoc
          If .Revisions.Count > 0 Then
            strReport = strReport & vbCr & .Name & vbTab & .Revisions.Count
          End If
          .Close SaveChanges:=False
        End With
      End If
      strFile = Dir()
    Wend
    If strReport <> "" Then
      strReport = "The following documents in contain tracked changes folder: & vbcr & strFolder & vbcr & strReport"
    Else
      strReport = "There are no documents containing tracked changes in folder: " & strFolder
    End If
    ActiveDocument.Range.Text = strReport
    Set wdDoc = Nothing
    Application.ScreenUpdating = True
    End Sub
    
    Function GetFolder() As String
    Dim oFolder As Object
    GetFolder = ""
    Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
    If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
    Set oFolder = Nothing
    End Function
    Whenever the macro is run, the 'Revisions Report' document's content will be overwritten with a report of all documents in the nominated folder than contain tracked changes.
    Cheers,

    Paul Edstein
    [MS MVP - Word]

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •