Results 1 to 11 of 11
  1. #1
    New Lounger
    Join Date
    Dec 2015
    Posts
    6
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Need Word macro for integrating Medline document with Mendeley add-on

    Hello,

    I need some help. I have a feeling that someone knows a more efficient way to accomplish what I end up doing manually.

    In the initial stages of a research idea, I like to take abstracts from Pubmed and then re-arrange them in a type of outline. I do this by removing everything but the date, title, abstract and PMID sections. This is done either by selecting lines and deleting or trying my luck with a wildcard search-replace strategy. Then for each PMID, I copy the PMID number, click the insert citation in the Mendeley add-on and paste the PMID number into the search box and press enter to insert the citation number.

    Here are 2 abstracts from Pubmed in Medline format (sometimes I may have 1-100 abstracts):

    PMID- 7319674
    OWN - NLM
    STAT- MEDLINE
    DA - 19820313
    DCOM- 19820313
    LR - 20071114
    IS - 0020-7136 (Print)
    IS - 0020-7136 (Linking)
    VI - 28
    IP - 3
    DP - 1981 Sep 15
    TI - Morbidity from cancer in La Paz, Bolivia.
    PG - 307-14
    AB - Data from a population-based Cancer Registry in La Paz, Bolivia, are presented.
    The city is located at approximately 4,000 meters above sea level and has a
    strong cultural influence consisting of Aymara Indians immigrating from the
    altiplano. Incidence rates in females are high for cancer of the cervix, the
    gallbladder and the thyroid gland. Males display unusually high rates of
    testicular cancer. Stomach cancer rates are lower than among other Andean
    populations. Smoking-related cancer and cancers related to sex-hormones are lower
    than average in incidence. Cancer of the nasal mucosa and paranasal sinuses is
    unusually high in frequency.
    FAU - Rios-Dalenz, J
    AU - Rios-Dalenz J
    FAU - Correa, P
    AU - Correa P
    FAU - Haenszel, W
    AU - Haenszel W
    LA - eng
    MH - Altitude
    MH - Bolivia
    SO - Int J Cancer. 1981 Sep 15;28(3):307-14.

    PMID- 24556225
    OWN - NLM
    STAT- MEDLINE
    DA - 20140328
    DCOM- 20150601
    IS - 1872-7573 (Electronic)
    IS - 0378-8741 (Linking)
    VI - 153
    IP - 1
    DP - 2014 Apr 11
    TI - Nepalese traditional medicine and symptoms related to Parkinson's disease and
    other disorders: Patterns of the usage of plant resources along the Himalayan
    altitudinal range.
    PG - 178-89
    LID - 10.1016/j.jep.2014.02.016 [doi]
    LID - S0378-8741(14)00117-2 [pii]
    AB - ETHNOPHARMACOLOGICAL RELEVANCE: Nepal is a hotspot for cultural and biological
    diversities. The tremendous diversity of ecosystems and climates and the blend of
    medicinal practices inherited from Ayurvedic and Traditional Tibetan Medicine are
    well suited to a study aimed at discovering information about medicinal plants to
    treat symptoms related to PD and other disorders across the
    Area). The documentation of community-natural resource relationships is another
    step in the preservation of traditional practices and local biodiversity and a
    reflection of communities' rights in the design of conservation programs.
    CI - Copyright (c) 2014 Elsevier Ireland Ltd. All rights reserved.
    FAU - de Rus Jacquet, Aurelie
    AU - de Rus Jacquet A
    MH - *Altitude
    MH - Conservation of Natural Resources/methods
    MH - Cross-Cultural Comparison
    MH - Ethnopharmacology
    MH - Humans
    MH - Medicine, Ayurvedic
    MH - Medicine, Traditional/methods
    SO - J Ethnopharmacol. 2014 Apr 11;153(1):178-89. doi: 10.1016/j.jep.2014.02.016. Epub
    2014 Feb 17.
    ********

    I would like the Macro to keep only the PMID, TI, DP and AB section to end up looking like : Date, Title, Abstract (I have abbreviated them below), the PMID (after the abstract) and the citation from Mendeley (in this case the [1] and [2].


    Here is an example of using the "insert citation" on Mendeley Word add-on to search for the PMID number and enter the citation (ex. [1]) after the abstract.

    NURPv.jpg


    If possible, I would also like to remove the headers DP, TI and AB, yielding something like:

    1981. Morbidity from cancer in La Paz, Bolivia. Data from a population-based Cancer Registry in La Paz,
    Bolivia, are presented… PMID:
    7319674 [1]

    2014. Nepalese traditional medicine and symptoms related to Parkinson's disease and other disorders:
    Patterns of the usage of plant resources along the Himalayan altitudinal range. ETHNOPHARMACOLOGICAL
    RELEVANCE: Nepal is a hotspot for cultural and biological … PMID:
    24556225 [2]


    It would be fantastic if the Macro did this for each Medline entry. If this is possible, I'll be sure to include an Acknowledgment in a paper.


    Thank you!

  2. #2
    Super Moderator
    Join Date
    May 2002
    Location
    Canberra, Australian Capital Territory, Australia
    Posts
    5,054
    Thanks
    2
    Thanked 417 Times in 346 Posts
    You don't really need a macro for this - unless the sequential numbering of the PMIDs is required. Otherwise, the lot could be done with a single wildcard Find/Replace, where:
    Find = (PMID[!^13]@^13)*DP - ([0-9]{4})*TI -([!^13]@)^13*AB -([!^13]@)^13*SO - [!^13]@^13
    Replace = \2\3\4 … \1

    Note: The above assumes every line with an acronym prefix is begins a new paragraph that continues until the next such entry (e.g. your abstract is all one paragraph).
    Cheers,

    Paul Edstein
    [MS MVP - Word]

  3. #3
    New Lounger
    Join Date
    Dec 2015
    Posts
    6
    Thanks
    0
    Thanked 0 Times in 0 Posts
    Quote Originally Posted by macropod View Post
    You don't really need a macro for this - unless the sequential numbering of the PMIDs is required. Otherwise, the lot could be done with a single wildcard Find/Replace, where:
    Find = (PMID[!^13]@^13)*DP - ([0-9]{4})*TI -([!^13]@)^13*AB -([!^13]@)^13*SO - [!^13]@^13
    Replace = \2\3\4 … \1

    Note: The above assumes every line with an acronym prefix is begins a new paragraph that continues until the next such entry (e.g. your abstract is all one paragraph).
    Thanks for the reply. One thing I forgot is that the abstracts looks like this (showing the formatting with a paragraph mark at the end of each line)
    when I paste into Word (it does this for Keep Formatting, Merge Formatting and Text). I don't know of a good way to "compact" the text
    so that it removes the paragraph marks to join the lines so that the abstract behaves as 1 paragraph (other than to do it manually).

    Just to double-check:
    Do I paste the bolded text into the Find box: (PMID[!^13]@^13)*DP - ([0-9]{4})*TI -([!^13]@)^13*AB -([!^13]@)^13*SO - [!^13]@^13
    (Should I leave the spaces around the dash "DP - (..." or remove the spaces "...DP-([0...)"?and the italicized text into Replace: \2\3\4 … \1 (leaving the spaces before and after the ...)?


    I removed the extra paragraph marks in the abstract and pasted the bolded text above in the Find box, but it reported "search item not found"

    Thanks again

  4. #4
    Super Moderator
    Join Date
    May 2002
    Location
    Canberra, Australian Capital Territory, Australia
    Posts
    5,054
    Thanks
    2
    Thanked 417 Times in 346 Posts
    Quote Originally Posted by bobmi View Post
    Do I paste the bolded text into the Find box: (PMID[!^13]@^13)*DP - ([0-9]{4})*TI -([!^13]@)^13*AB -([!^13]@)^13*SO - [!^13]@^13
    (Should I leave the spaces around the dash "DP - (..." or remove the spaces "...DP-([0...)"?and the italicized text into Replace: \2\3\4 … \1 (leaving the spaces before and after the ...)?

    I removed the extra paragraph marks in the abstract and pasted the bolded text above in the Find box, but it reported "search item not found"
    You should use the Find/Replace code exactly as provided. Did you check the 'use wildcards' option?

    If you want to clean up the text without having to delete the paragraph breaks in the abstracts, you could use:
    Find = (PMID[!^13]@^13)*DP - ([0-9]{4})*TI -([!^13]@)^13*AB -(*)^13[CF][IA]*SO - [!^13]@^13

    The following macro should do almost all of the clean-up for you. You may have to edit the final entry, though, if that record's last item had a paragraph break in it (as you second example has). You may also get an extraneous numbered paragraph at the end.
    Code:
    Sub CleanUpPubmedText()
    'Turn Off Screen Updating
    Application.ScreenUpdating = False
    Dim i As Long
    With ActiveDocument.Range
      With .Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchAllWordForms = False
        .MatchSoundsLike = False
        .MatchWildcards = True
        'Eliminate extraneous content
        .Text = "(PMID[!^13]@^13)*DP - ([0-9]{4})*TI -([!^13]@)^13*AB -(*)^13[CF][IA]*SO - [!^13]@^13"
        .Replacement.Text = "\2\3\4 … \1"
        .Execute Replace:=wdReplaceAll
        'Replace single paragraph breaks with a space
        .Text = "([!^13])([^13])([!^13])"
        .Replacement.Text = "\1 \3"
        .Execute Replace:=wdReplaceAll
        'Replace all double spaces with single spaces
        .Text = "[ ]{2,}"
        .Replacement.Text = " "
        .Execute Replace:=wdReplaceAll
        'Delete hypens in hyphenated text formerly split across lines
        .Text = "([a-z])-[ ]{1,}([a-z])"
        .Replacement.Text = "\1\2"
        .Execute Replace:=wdReplaceAll
        'Limit paragraph breaks to one per 'real' paragraph.
        .Text = "[^13]{1,}"
        .Replacement.Text = "^p"
        .Execute Replace:=wdReplaceAll
      End With
      For i = 1 To .Paragraphs.Count
        .Paragraphs(i).Range.Characters.Last.InsertBefore " [" & i & "]"
      Next
    End With
    'Restore Screen Updating
    Application.ScreenUpdating = True
    End Sub
    Last edited by macropod; 2015-12-15 at 16:08.
    Cheers,

    Paul Edstein
    [MS MVP - Word]

  5. #5
    New Lounger
    Join Date
    Dec 2015
    Posts
    6
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Getting closer...

    Thanks Paul,

    I attached a text file that has 5 abstracts in Medline format I have been working with (I hope it attaches). I wasn't sure if the Keep formatting, Merge formatting or Text would affect the outcome, so I just used text format. I tried to do the manual find and replace strategy and ended up with "search item not found" (pic below). I also tried my luck with Find and Replace in Notepad, Notepad++, and Excel to no avail.

    After running the Macro I ended up with:



    Thanks again for your help,


    Quote Originally Posted by macropod View Post
    You should use the Find/Replace code exactly as provided. Did you check the 'use wildcards' option?

    If you want to clean up the text without having to delete the paragraph breaks in the abstracts, you could use:
    Find = (PMID[!^13]@^13)*DP - ([0-9]{4})*TI -([!^13]@)^13*AB -(*)^13[CF][IA]*SO - [!^13]@^13

    The following macro should do almost all of the clean-up for you. You may have to edit the final entry, though, if that record's last item had a paragraph break in it (as you second example has). You may also get an extraneous numbered paragraph at the end.
    Code:
    Sub CleanUpPubmedText()
    'Turn Off Screen Updating
    Application.ScreenUpdating = False
    Dim i As Long
    With ActiveDocument.Range
      With .Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchAllWordForms = False
        .MatchSoundsLike = False
        .MatchWildcards = True
        'Eliminate extraneous content
        .Text = "(PMID[!^13]@^13)*DP - ([0-9]{4})*TI -([!^13]@)^13*AB -(*)^13[CF][IA]*SO - [!^13]@^13"
        .Replacement.Text = "\2\3\4 … \1"
        .Execute Replace:=wdReplaceAll
        'Replace single paragraph breaks with a space
        .Text = "([!^13])([^13])([!^13])"
        .Replacement.Text = "\1 \3"
        .Execute Replace:=wdReplaceAll
        'Replace all double spaces with single spaces
        .Text = "[ ]{2,}"
        .Replacement.Text = " "
        .Execute Replace:=wdReplaceAll
        'Delete hypens in hyphenated text formerly split across lines
        .Text = "([a-z])-[ ]{1,}([a-z])"
        .Replacement.Text = "\1\2"
        .Execute Replace:=wdReplaceAll
        'Limit paragraph breaks to one per 'real' paragraph.
        .Text = "[^13]{1,}"
        .Replacement.Text = "^p"
        .Execute Replace:=wdReplaceAll
      End With
      For i = 1 To .Paragraphs.Count
        .Paragraphs(i).Range.Characters.Last.InsertBefore " [" & i & "]"
      Next
    End With
    'Restore Screen Updating
    Application.ScreenUpdating = True
    End Sub
    Attached Files Attached Files

  6. #6
    New Lounger
    Join Date
    Dec 2015
    Posts
    6
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Found a workaround

    Thanks again Paul!

    I tried several different options and stumbled across a workaround. Somehow, I stumbled across Pubmed2xl, which takes the Medline xml and
    converts it to Excel. Then, I just select the columns I need, Ctrl-C, and paste as text into Word. I wouldn't have found it without your help.

    I did try and create a Macro for assigning the Mendeley-generated citation for the PMID but didn't have much luck. I think I read
    that there was a way to select a number with a certain amount of digits. But have not been successful using the Alt+M shortcut to try and paste the PMID number in the Mendeley search box. This is what the text looks like pasted from Pubmed2xl. Any ideas?


  7. #7
    Super Moderator
    Join Date
    May 2002
    Location
    Canberra, Australian Capital Territory, Australia
    Posts
    5,054
    Thanks
    2
    Thanked 417 Times in 346 Posts
    The content of your text file is rather different from what you had posted, especially regarding space padding. Try:
    Code:
    Sub CleanUpPubmedText()
    'Turn Off Screen Updating
    Application.ScreenUpdating = False
    Dim i As Long
    With ActiveDocument.Range
      With .Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchAllWordForms = False
        .MatchSoundsLike = False
        .MatchWildcards = True
        'Replace all paragraphs followed by spaces with single spaces
        .Text = "^13[ ]{2,}"
        .Replacement.Text = " "
        .Execute Replace:=wdReplaceAll
        'Replace all double spaces with single spaces
        .Text = "[ ]{2,}"
        .Replacement.Text = " "
        .Execute Replace:=wdReplaceAll
        'Make Titles Bold
        .Text = "TI -([!^13]@)^13"
        .Replacement.Text = "^&"
        .Replacement.Font.Bold = True
        .Execute Replace:=wdReplaceAll
        .Replacement.ClearFormatting
        'Eliminate extraneous content
        .Text = "(PMID[!^13]@^13)*DP - ([0-9]{4})*TI -([!^13]@)^13*AB -(*)^13[CF][IA]*SO - [!^13]@^13"
        .Replacement.Text = "\2\3\4 … \1"
        .Execute Replace:=wdReplaceAll
        'Limit paragraph breaks to one per 'real' paragraph.
        .Text = "[^13]{1,}"
        .Replacement.Text = "^p"
        .Execute Replace:=wdReplaceAll
      End With
      While .Characters.Last.Previous = vbCr
        .Characters.Last.Previous.Delete
      Wend
      For i = 1 To .Paragraphs.Count
        .Paragraphs(i).Range.Characters.Last.InsertBefore " [" & i & "]"
      Next
    End With
    'Restore Screen Updating
    Application.ScreenUpdating = True
    End Sub
    Cheers,

    Paul Edstein
    [MS MVP - Word]

  8. #8
    New Lounger
    Join Date
    Dec 2015
    Posts
    6
    Thanks
    0
    Thanked 0 Times in 0 Posts
    Quote Originally Posted by macropod View Post
    The content of your text file is rather different from what you had posted, especially regarding space padding. Try:
    Code:
    Sub CleanUpPubmedText()
    'Turn Off Screen Updating
    Application.ScreenUpdating = False
    Dim i As Long
    With ActiveDocument.Range
      With .Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchAllWordForms = False
        .MatchSoundsLike = False
        .MatchWildcards = True
        'Replace all paragraphs followed by spaces with single spaces
        .Text = "^13[ ]{2,}"
        .Replacement.Text = " "
        .Execute Replace:=wdReplaceAll
        'Replace all double spaces with single spaces
        .Text = "[ ]{2,}"
        .Replacement.Text = " "
        .Execute Replace:=wdReplaceAll
        'Make Titles Bold
        .Text = "TI -([!^13]@)^13"
        .Replacement.Text = "^&"
        .Replacement.Font.Bold = True
        .Execute Replace:=wdReplaceAll
        .Replacement.ClearFormatting
        'Eliminate extraneous content
        .Text = "(PMID[!^13]@^13)*DP - ([0-9]{4})*TI -([!^13]@)^13*AB -(*)^13[CF][IA]*SO - [!^13]@^13"
        .Replacement.Text = "\2\3\4 … \1"
        .Execute Replace:=wdReplaceAll
        'Limit paragraph breaks to one per 'real' paragraph.
        .Text = "[^13]{1,}"
        .Replacement.Text = "^p"
        .Execute Replace:=wdReplaceAll
      End With
      While .Characters.Last.Previous = vbCr
        .Characters.Last.Previous.Delete
      Wend
      For i = 1 To .Paragraphs.Count
        .Paragraphs(i).Range.Characters.Last.InsertBefore " [" & i & "]"
      Next
    End With
    'Restore Screen Updating
    Application.ScreenUpdating = True
    End Sub

    Sorry about that, I had pasted the file directly from Pubmed into Notepad, and on the others I pasted into word. I did notice that when I open the file in Word (instead of pasting) and select Unicode that it also affects the formatting.

    Below is a pic where I pasted the contents from notepad into Word (left side) and ran the macro (right side). It looks like the Macro is entering bracketed numbers sequentially.

    I have tried to play with the macro below and use "[0-9]{8,}" to find the 8-digit PMID
    When I run the Macro, it doesn't paste the 8-digit number into Mendeley box automatically. The Mendeley box pops open, then
    if hit Ctrl-V it will paste the PMID number in. Then I press OK and the macro finds the next 8-digit PMID, the Mendeley box opens, I press
    Ctrl-V again and press OK.



    I'm not sure how to get to paste the 8-digit number automatically and the press the OK button. Hitting enter results in Mendeley expecting another citation to be entered at the same location (ex. Smith, 2014; Jones, 2013). Also, I don't know how to have the Macro keep searchin until it reaches the last PMID.

    Code:
    Sub Macro2()
    '
    ' Macro2 Macro
    '
    '
        Selection.Find.ClearFormatting
        Selection.Find.Replacement.ClearFormatting
        With Selection.Find
            .Text = "[0-9]{8,}"
            .Replacement.Text = ""
            .Forward = True
            .Wrap = wdFindContinue
            .Format = False
            .MatchCase = False
            .MatchWholeWord = False
            .MatchAllWordForms = False
            .MatchSoundsLike = False
            .MatchWildcards = True
        End With
        Selection.Find.Execute
        Selection.Copy
        Application.Run MacroName:="MendeleyPlugin.Mendeley.insertCitation"
        Selection.Find.ClearFormatting
        Selection.Find.Replacement.ClearFormatting
        With Selection.Find
            .Text = "[0-9]{8,}"
            .Replacement.Text = ""
            .Forward = True
            .Wrap = wdFindContinue
            .Format = False
            .MatchCase = False
            .MatchWholeWord = False
            .MatchAllWordForms = False
            .MatchSoundsLike = False
            .MatchWildcards = True
        End With
        Selection.Find.Execute
        Selection.Copy
        Application.Run MacroName:="MendeleyPlugin.Mendeley.insertCitation"
        Selection.Find.ClearFormatting
        Selection.Find.Replacement.ClearFormatting
        With Selection.Find
            .Text = "[0-9]{8,}"
            .Replacement.Text = ""
            .Forward = True
            .Wrap = wdFindContinue
            .Format = False
            .MatchCase = False
            .MatchWholeWord = False
            .MatchAllWordForms = False
            .MatchSoundsLike = False
            .MatchWildcards = True
        End With
        Selection.Find.Execute
        Selection.Copy
        Application.Run MacroName:="MendeleyPlugin.Mendeley.insertCitation"
        Selection.Find.ClearFormatting
        Selection.Find.Replacement.ClearFormatting
        With Selection.Find
            .Text = "[0-9]{8,}"
            .Replacement.Text = ""
            .Forward = True
            .Wrap = wdFindContinue
            .Format = False
            .MatchCase = False
            .MatchWholeWord = False
            .MatchAllWordForms = False
            .MatchSoundsLike = False
            .MatchWildcards = True
        End With
        Selection.Find.Execute
        Selection.Copy
        Application.Run MacroName:="MendeleyPlugin.Mendeley.insertCitation"
        Selection.Find.ClearFormatting
        Selection.Find.Replacement.ClearFormatting
        With Selection.Find
            .Text = "[0-9]{8,}"
            .Replacement.Text = ""
            .Forward = True
            .Wrap = wdFindContinue
            .Format = False
            .MatchCase = False
            .MatchWholeWord = False
            .MatchAllWordForms = False
            .MatchSoundsLike = False
            .MatchWildcards = True
        End With
        Selection.Find.Execute
        Selection.Copy
        Application.Run MacroName:="MendeleyPlugin.Mendeley.insertCitation"
        Selection.Find.ClearFormatting
        Selection.Find.Replacement.ClearFormatting
        With Selection.Find
            .Text = "[0-9]{8,}"
            .Replacement.Text = ""
            .Forward = True
            .Wrap = wdFindContinue
            .Format = False
            .MatchCase = False
            .MatchWholeWord = False
            .MatchAllWordForms = False
            .MatchSoundsLike = False
            .MatchWildcards = True
        End With
        Selection.Find.Execute
    End Sub

  9. #9
    Super Moderator
    Join Date
    Jan 2001
    Location
    Melbourne, Victoria, Australia
    Posts
    3,852
    Thanks
    4
    Thanked 259 Times in 239 Posts
    Do these citation sources not provide an XML export option?

    If you can get hold of structured data then choosing to show only a subset of that is much easier than trying to anticipate what kind of content the macro might encounter.
    Andrew Lockton, Chrysalis Design, Melbourne Australia

  10. #10
    Super Moderator
    Join Date
    May 2002
    Location
    Canberra, Australian Capital Territory, Australia
    Posts
    5,054
    Thanks
    2
    Thanked 417 Times in 346 Posts
    Quote Originally Posted by bobmi View Post
    Sorry about that, I had pasted the file directly from Pubmed into Notepad, and on the others I pasted into word. I did notice that when I open the file in Word (instead of pasting) and select Unicode that it also affects the formatting.

    ...

    I have tried to play with the macro below and use "[0-9]{8,}" to find the 8-digit PMID
    When I run the Macro, it doesn't paste the 8-digit number into Mendeley box automatically. The Mendeley box pops open, then
    if hit Ctrl-V it will paste the PMID number in. Then I press OK and the macro finds the next 8-digit PMID, the Mendeley box opens, I press
    Ctrl-V again and press OK.

    I'm not sure how to get to paste the 8-digit number automatically and the press the OK button. Hitting enter results in Mendeley expecting another citation to be entered at the same location (ex. Smith, 2014; Jones, 2013). Also, I don't know how to have the Macro keep searchin until it reaches the last PMID.
    You seem to be continually moving the goal posts. The first macro I posted, processed the data as you had posted it; the second macro processes the content of your notepad file. Your latest post suggests you're working with something different to either of those! Not only that, you now also seem to want something else to do with your Mendeley Plugin. Since I have never used the Mendeley Plugin, I can't really help you with that.
    Cheers,

    Paul Edstein
    [MS MVP - Word]

  11. #11
    New Lounger
    Join Date
    Dec 2015
    Posts
    6
    Thanks
    0
    Thanked 0 Times in 0 Posts
    Quote Originally Posted by macropod View Post
    You seem to be continually moving the goal posts. The first macro I posted, processed the data as you had posted it; the second macro processes the content of your notepad file. Your latest post suggests you're working with something different to either of those! Not only that, you now also seem to want something else to do with your Mendeley Plugin. Since I have never used the Mendeley Plugin, I can't really help you with that.
    Sorry for any trouble, maybe me asking what would be the best way to accomplish the desired outcome (without any preconceptions on my part ) would have been a better approach. Thanks again for your efforts.

Tags for this Thread

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •