Results 1 to 4 of 4
  1. #1
    Lounger
    Join Date
    Feb 2001
    Location
    Ohio, USA
    Posts
    46
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Minimize App on run (2000)

    I am looking for a way to minimize the app window when starting Access. Everything I have tried minimizes the DB window but not the entire app. Is there anyway to do what I'm asking?

    Thanks,
    Pat Russell
    Process Automation Engineer

  2. #2
    5 Star Lounger
    Join Date
    Jul 2002
    Location
    Toronto, Ontario, Canada
    Posts
    1,139
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Re: Minimize App on run (2000)

    Pat,

    I don't know if there is a method built into Access to minimize the whole application, but you can use API calls to do it.

    Just have a look at <post#=228487>post 228487</post#>. It will give you a way to do it with APIs.
    --
    Bryan Carbonnell - Toronto <img src=/S/flags/Ontario.gif border=0 alt=Ontario width=30 height=18> <img src=/S/flags/Canada.gif border=0 alt=Canada width=30 height=18>
    Unfortunately common sense isn't so common!!
    Visit my website for useful Word, Excel and Access code, templates and Add-Ins

  3. #3
    Plutonium Lounger
    Join Date
    Mar 2002
    Posts
    84,353
    Thanks
    0
    Thanked 29 Times in 29 Posts

    Re: Minimize App on run (2000)

    A very simple way is to use a shortcut to open Access. In the properties of a shortcut, you can specify whether Access starts normal, maximized or minimized.

    If you want to do it from Access itself, you need Windows API calls to accomplish it:

    1. Create a standard module and copy the following code into it:

    Private Type Rect
    X1 As Long
    Y1 As Long
    X2 As Long
    Y2 As Long
    End Type

    Private Type PointAPI
    x As Long
    y As Long
    End Type

    Private Type WindowPlacement
    Length As Long
    Flags As Long
    showCmd As Long
    ptMinPosition As PointAPI
    ptMaxPosition As PointAPI
    rcNormalPosition As Rect
    End Type

    Private Declare Function GetWindowPlacement Lib "user32" _
    (ByVal hWnd As Long, lpWndPl As WindowPlacement) As Long

    Private Declare Function SetWindowPlacement Lib "user32" _
    (ByVal hWnd As Long, lpWndPl As WindowPlacement) As Long

    Public Const SW_Maximize = 3
    Public Const SW_Minimize = 6
    Public Const SW_Restore = 9

    Public Function AccessWindow(sw As Long)
    Dim wp As WindowPlacement
    wp.Length = Len(wp)
    GetWindowPlacement Application.hWndAccessApp, wp
    wp.showCmd = sw
    SetWindowPlacement Application.hWndAccessApp, wp
    End Function

    2. To minimize the Access application window, call AccessWindow(6), for instance in an AutoExec macro or in the OnLoad event of the startup form of your database (6 = SW_Minimize, but you can't use a constant in a macro).

  4. #4
    Lounger
    Join Date
    Feb 2001
    Location
    Ohio, USA
    Posts
    46
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Re: Minimize App on run (2000)

    Thanks! I used a combination of both methods to get my desired results, works great.
    Pat Russell
    Process Automation Engineer

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •