Access text in bound textbox (2000)

[IanR]

I'm having trouble getting to the text that is currently displayed in a bound text box. I'm trying to provide a keyboard shortcut for users to insert @ signs into email addresses on PCs that do not have full keyboards. I'm using onKeyPress to trap a control + key combination (I've selected Ctl+E as all the obvious ones have gone). The control in question is called txtEmail and is bound to a text field. In the KeyPress event I use

strEmail = Me.txtEmail
strEmail = strEmail & "@"
Me.txtEmail = strEmail
Me.txtEmail.SelStart = Len(Me.txtEmail)

This adds the @ sign, deselects the text then places the insertion point at the end of the new string ready for the rest of the email. However, if there is already an entry in this field, which has to be changed, when the user deletes the previous entry, enters the new address and presses Clt+E, the old entry reappears and the new entry is lost.

Obviously for fields that already contain data Me.txtEmail is looking at the saved entry in the table. Is there a way of referencing the current contents of the textbox rather than the contents of the bound field?

Ian

[charlotte]

<hr>referencing the current contents of the textbox rather than the contents of the bound field<hr>

When you are editing, you are addressing the current contents rather than the field. The changes aren't written back to the field until the AfterUpdate event of the control. You only posted a snippet of code. Is there more after that?

[IanR]

Not much more, this is the lot.

Private Sub txtEmail_KeyPress(KeyAscii As Integer)
' Provide @ sign. About the only spare Ctl-Key combination left that makes
' any sense is Ctl-E (for e-mail, geddit)

Const TrapKey = 5
Dim strEmail As String

If KeyAscii = TrapKey Then
strEmail = Me.txtEmail
strEmail = strEmail & "@"
Me.txtEmail = strEmail
Me.txtEmail.SelStart = Len(Me.txtEmail)
End If

End Sub

[HansV]

When you refer to Me.txtEmail without specifying a property, Access silently uses the default property of the text box, i.e. the stored Value. To refer to the uncommitted text currently being entered, use the Text property:

Me.txtEmail.Text

But you can't use Ctrl+E, for the KeyPress event only reacts to "character" keys, not to function keys or combinations with Ctrl etc. You must use the KeyDown (or KeyUp) event to handle Ctrl+key combinations. Try this:

Private Sub txtEmail_KeyDown(KeyCode As Integer, Shift As Integer)
If KeyCode = vbKeyE And (Shift And acCtrlMask) > 0 Then
' Insert @
txtEmail.Text = txtEmail.Text & "@"
txtEmail.SelStart = Len(txtEmail.Text)
' Prevent further handling of keystroke
KeyCode = 0
End If
End Sub

[IanR]

Thanks for the tip Hans, the Text property did the trick.

However (1) I think you're wrong about KeyPress, which does allow combinations of letters with the Control key.

However (2) It won't allow combinations with the Alt key. To put in an @ sign it would make more sense from a user's point of view to use something like Alt-A. How do I modify your code to do that? Does

If KeyCode = vbKeyE And (Shift And acCtrlMask) > 0 Then

become

If KeyCode = vbKeyA And (Shift And acAltMask) > 0 Then

?

[HansV]

Hi Ian,

You're quite right about KeyPress being able to handle Ctrl+letter combinations. Somehow, it escaped my attention - it is mentioned in the online help.

However, KeyPress can't handle Alt, Ctrl+Alt, Shift+Alt, Ctrl+Shift etc. You need KeyDown or KeyUp for that. The Shift parameter can consist of any combination of acShiftMask, acAltMask and acCtrlMask. To test if one of these applies, test if (Shift and ac...Mask) > 0.