Results 1 to 6 of 6
  1. #1
    New Lounger
    Join Date
    Apr 2003
    Location
    Cleveland, Ohio, USA
    Posts
    4
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Reminder in Access (2000)

    I need to create a reminder that will pop up in access, when the user is working in Access, no matter what form they are working on. The reminder should have the capacity to be set to a certain date and time and have a snooze feature. Just like the one in outlook. Can this be done?

    Bill

  2. #2
    Super Moderator
    Join Date
    Aug 2001
    Location
    Evergreen, CO, USA
    Posts
    6,623
    Thanks
    3
    Thanked 60 Times in 60 Posts

    Re: Reminder in Access (2000)

    Yes, it can be done, but it is lots of work. A simpler solution would be to create an Outlook reminder using Automation, since Outlook already has all the reminder stuff built in. In any event either approach would involve using VBA. Are you comfortable with that?
    Wendell

  3. #3
    New Lounger
    Join Date
    Apr 2003
    Location
    Cleveland, Ohio, USA
    Posts
    4
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Re: Reminder in Access (2000)

    Yes, I am comfortable with VBA. I tried the Automation link, but I kept getting errors. I will try to find this on the web.

    TIA
    Bill

  4. #4
    Super Moderator
    Join Date
    Aug 2001
    Location
    Evergreen, CO, USA
    Posts
    6,623
    Thanks
    3
    Thanked 60 Times in 60 Posts

    Re: Reminder in Access (2000)

    I presume you are referring to the Automation tutorial in my signature line - what browser are you running? It seems to work just fine in Internet Explorer. FYI, you can get to it by going to our home page http://www.access-experts.com, then choosing the support menu option, which should expand to show you several categories, one of them being Tutorials. Click on that to go to a list of tutorials, and the Automation 101 tutorial should be at the top of the list. Let me have some feedback as this is the first case where someone has complained about not being able to get to one of our web pages. Thanks.
    Wendell

  5. #5
    Plutonium Lounger
    Join Date
    Mar 2002
    Posts
    84,353
    Thanks
    0
    Thanked 29 Times in 29 Posts

    Re: Reminder in Access (2000)

    I agree with Wendell that using Outlook is probably best, since that has everything needed for reminders built in.

    It is possible, though, to create a reminder form in Access. You need a popup form with an On Timer event handler. I have attached a simple demo with just the popup form. The "Start" button runs the following code:

    Private Sub cmdStart_Click()
    If IsNull(Me.txtDateTime) Then
    MsgBox "Please set a reminder time.", vbExclamation
    Exit Sub
    ElseIf DateValue(Me.txtDateTime) + TimeValue(Me.txtDateTime) <= Now Then
    MsgBox "The reminder time is in the past.", vbExclamation
    Exit Sub
    End If
    Me.TimerInterval = 10000
    Me.Visible = False
    End Sub

    After some checks, it sets the timer interval to 10000 milliseconds = 10 seconds, and hides itself. The On Timer event handler looks like this:

    Private Sub Form_Timer()
    If Now >= DateValue(Me.txtDateTime) + TimeValue(Me.txtDateTime) Then
    Beep
    Me.Visible = True
    Me.TimerInterval = 0
    Me.txtDelay.Visible = True
    Me.cmdSnooze.Visible = True
    Me.lblMinutes.Visible = True
    End If
    End Sub

    If the current date/time is past the set date/time, the timer is turned off by setting the timer interval to 0, the form unhides itself and displays the snooze controls.

    The "Snooze" button does this:

    Private Sub cmdSnooze_Click()
    Me.TimerInterval = 10000
    Me.txtDateTime = Now + TimeSerial(0, txtDelay, 0)
    Me.Visible = False
    End Sub

    It sets the target time to now plus the user-specified delay, starts the timer, and hides itself.

    Finally, the Cancel button just closes the form (effectively stopping the timer):

    Private Sub cmdCancel_Click()
    DoCmd.Close acForm, Me.Name
    End Sub
    Attached Files Attached Files

  6. #6
    New Lounger
    Join Date
    Apr 2003
    Location
    Cleveland, Ohio, USA
    Posts
    4
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Re: Reminder in Access (2000)

    Great! This is just what I wanted! Thanks!

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •