Results 1 to 8 of 8
  1. #1
    New Lounger
    Join Date
    Jan 2002
    Posts
    6
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Exporting vCards to Ipod (XP)

    I want to export multiple contacts to my Ipod as vCards. My initial explorations have failed. So far I have "forwarded" all my contacts to a new message and then tried to ctrl-a them and drag them to the open Ipod window -- no luck. It works for single cards but no more. Any ideas? (WIndows XP Home with Office XP)

    Thanks.

  2. #2
    5 Star Lounger
    Join Date
    May 2001
    Location
    Washington, USA
    Posts
    750
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Re: Exporting vCards to Ipod (XP)

    vCard isn't designed for a batch transaction. I look for code options and didn't find anything there either. Can you get by with an export/import?

  3. #3
    New Lounger
    Join Date
    Jan 2002
    Posts
    6
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Re: Exporting vCards to Ipod (XP)

    Thanks for the idea. I would use export but I don't know how to get from any of the "Outlook-acceptable" formats to vCard. Any ideas?

  4. #4
    Super Moderator jscher2000's Avatar
    Join Date
    Feb 2001
    Location
    Silicon Valley, USA
    Posts
    23,112
    Thanks
    5
    Thanked 93 Times in 89 Posts

    Re: Exporting vCards to Ipod (XP)

    Inclined to try a macro? I just threw this together and tested a little bit. It probably has some issues I didn't discover, but might get you further down the road:

    <pre>Sub ExportvCards()
    ' Saves currently selected contact records as vCards
    ' Check for and create export folder if needed
    If Dir("c:vCards", vbDirectory) = vbNullString Then
    MkDir "c:vCards"
    End If
    ' Export contacts; this will overwrite if there are duplicates
    ' when using FullName
    Dim olContact As ContactItem
    On Error Resume Next
    For Each olContact In ActiveExplorer.Selection
    ' Inline error handling for bad item types
    If Err.Number = 13 Then
    MsgBox "You can do this only in a Contacts folder."
    Exit Sub
    ElseIf Err.Number <> 0 Then
    MsgBox "Error No. " & Err.Number & vbCrLf & """" & Err.Description & """"
    Exit Sub
    End If
    On Error GoTo 0
    With olContact
    If Trim(.FullName) <> vbNullString Then
    ' Save using FullName.vcf as the file name
    .SaveAs "c:vCards" & Trim(.FullName) & ".vcf", olVCard
    Else
    ' No full name (!!), substitute an almost certainly unique value
    .SaveAs "c:vCards" & CStr(Timer()) & ".vcf", olVCard
    End If
    End With
    Next
    End Sub</pre>

    Does this help?

  5. #5
    New Lounger
    Join Date
    Jan 2002
    Posts
    6
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Re: Exporting vCards to Ipod (XP)

    Thanks, I'll give it a try.

  6. #6
    New Lounger
    Join Date
    May 2004
    Location
    St. John, Virgin Islands, USA
    Posts
    14
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Re: Exporting vCards to Ipod (XP)

    I need the batch export also for iPod. I run the macro and get the error message "Time-run error '13': Typemismatch" Runing the De###### shows Next highlighted.
    I get the vCard folder setup with about 80 of 839 items in it.

    It works fine with one card selected. But when I select all and run the macro, I get the above.

  7. #7
    Super Moderator jscher2000's Avatar
    Join Date
    Feb 2001
    Location
    Silicon Valley, USA
    Posts
    23,112
    Thanks
    5
    Thanked 93 Times in 89 Posts

    Re: Exporting vCards to Ipod (XP)

    Maybe there is something your Contacts folder that is not a ContactItem? Try this version:

    <pre>Sub ExportvCards2()
    ' Original: 7/7/2003 Ver. 2: 5/28/2004 (changed type checking)
    ' Saves currently selected contact records as vCards
    ' Check for and create export folder if needed
    If Dir("c:vCards", vbDirectory) = vbNullString Then
    MkDir "c:vCards"
    End If
    ' Export contacts; this will overwrite if there are duplicates
    ' when using FullName
    Dim objContact As Object 'ContactItem can cause errors
    For Each objContact In ActiveExplorer.Selection
    If TypeName(objContact) <> "ContactItem" Then
    If MsgBox("Selected object is not a Contact. It is a """ & _
    TypeName(objContact) & """. Continue with the next one?", _
    vbExclamation + vbYesNo) = vbNo Then
    Exit For
    End If
    Else
    With objContact
    If Trim(.FullName) <> vbNullString Then
    ' Save using FullName.vcf as the file name
    .SaveAs "c:vCards" & Trim(.FullName) & ".vcf", olVCard
    Else
    ' No full name (!!), substitute an almost certainly unique value
    .SaveAs "c:vCards" & CStr(Timer()) & ".vcf", olVCard
    End If
    End With
    End If
    Next
    If Not (objContact Is Nothing) Then Set objContact = Nothing
    End Sub</pre>

    I'm curious what the dialog reports for the rogue items.

  8. #8
    New Lounger
    Join Date
    May 2004
    Location
    St. John, Virgin Islands, USA
    Posts
    14
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Re: Exporting vCards to Ipod (XP)

    Aha! I found two. One was a Web address http://etc. where I had support phones and e-mail. Another appeared to be regular entry - I couldn't find what the problem was. Anyhow deleting both solved the problem and the original marco extracted the Contacts as vCards.

    Thanks for your expert help.

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •