Results 1 to 2 of 2
  1. #1
    New Lounger
    Join Date
    Sep 2002
    Location
    Brandon, Manitoba, Canada
    Posts
    8
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Outlook 97 (Windows 98)

    All my e-mails being received have a received date of August 1, 2003 (even if sent today!) The date/time on the computer clock is correct -- any ideas on what may have caused this and how to correct it?

    Thank you
    Marie

  2. #2
    Super Moderator jscher2000's Avatar
    Join Date
    Feb 2001
    Location
    Silicon Valley, USA
    Posts
    23,112
    Thanks
    5
    Thanked 93 Times in 89 Posts

    Re: Outlook 97 (Windows 98)

    Generally speaking, the Received date is the date it was received by the mail server from which you retrive messages. To get more insight into the different dates, open a message, then choose Tools>Forms>Design this form. Click the (All Fields) tab and use the drop-down to change to All Mail Fields. Here's my best interpretation:

    Created: For mail you received, this is the date/time you downloaded it to Outlook.
    Modified: Initially the same as created, but updated if, say, you reply or forward the message.
    Received: The time the message landed on your mail server.
    Sent: The time the message says it was sent; this can be forged, so it's not reliable.

    Make sure to close the message without saving!

    If you want to look at these values often, you can save a macro and put a button for it on a toolbar. Here's the one I use. It's been a while since I wrote it, but not so long that I can be sure it works in Outlook 97. Just don't know.
    <pre>Option Explicit
    Public Sub MessageTimes()
    ' Show relevant times and dates for e-mail messages
    ' Jefferson Scher 2002-03-21; updated 2002-11-09
    Dim msg As MailItem, lngMinutes As Long, lngSeconds As Long
    If TypeName(Outlook.ActiveWindow) = "Inspector" Then
    If TypeName(ActiveInspector.CurrentItem) <> "MailItem" Then
    MsgBox "This only works with e-mail messages, sorry."
    Exit Sub
    End If
    ' Work with the open message
    Set msg = ActiveInspector.CurrentItem
    Else
    If ActiveExplorer.Selection.Count <> 1 Then
    MsgBox "Please highlight one message so I can calculate the elapsed minutes."
    Exit Sub
    End If
    If TypeName(ActiveExplorer.Selection.Item(1)) <> "MailItem" Then
    MsgBox "This only works with e-mail messages, sorry."
    Exit Sub
    End If
    ' Work with the selected message
    Set msg = ActiveExplorer.Selection.Item(1)
    End If
    ' Show different messages depending on sent or received (which is
    ' inferred from the times in the message)
    If msg.Sent = False Then
    MsgBox "This message has not been sent yet, so there is no valid time information " _
    & "to calculate. Sorry."
    Exit Sub
    End If
    ' problem with following is it rounds up
    'lngMinutes = DateDiff("n", msg.CreationTime, msg.SentOn)
    lngSeconds = DateDiff("s", msg.CreationTime, msg.SentOn)
    lngMinutes = Int(lngSeconds / 60)
    If lngSeconds > 0 Then 'This was a Sent message
    MsgBox "Creation Time: " & msg.CreationTime & vbCrLf & _
    "Message Sent: " & msg.SentOn & vbCrLf & vbCrLf & _
    "Elapsed Time: " & lngMinutes & " minutes, " & _
    lngSeconds - (lngMinutes * 60) & " seconds ", _
    vbInformation + vbOKOnly, "Sent Message Times by JFS"
    Else 'This was a Received message
    MsgBox "Message Sent: " & msg.SentOn & vbCrLf & _
    "Recd @Server: " & msg.ReceivedTime & vbCrLf & _
    "Retrieved Msg: " & msg.CreationTime & vbCrLf & _
    "Modified in OL: " & msg.LastModificationTime & " ", _
    vbInformation + vbOKOnly, "Received Message Times by JFS"
    End If
    Set msg = Nothing
    End Sub</pre>

    Hope this helps.

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •