Parsing cell (excel 2000)

[Torquemada]

Someone gave me a worksheet with a number of cells that have hard-coded numbers in them, eg. 5445.33+224.77-44+65. Lots of numbers. Now, I need to parse them out (with their proper sign) so that I can show the detail. Since there are multiple numbers, I am thinking about some kind of miracle macro that will put the string into a variable, and then maybe do/while len(var)>0, find the next "+224.77" , strip it out of the variable, write it to a new cell as a value, then save the now-shorter string back to the variable again, and start the process anew.
Does this make sense? Can someone suggest a basic set of code to do this. I'll bet there are plenty of users that might find it useful.
Thanks.

[JohnBF]

Are they in one column each with a leading = sign? If so, Find-&-Replace the leading = sign with a text character, then use Data, Text-to-Columns.

[HansV]

Does this do what you want? For production work, you would need to add error handling.

Sub ParseCells()
Dim oCell As Range
Dim lngOffset As Long
Dim lngOldPos As Long
Dim lngPos As Long
Dim strValue As String
Dim strTemp As String

For Each oCell In Selection
strValue = oCell.Value
If Not strValue = "" Then
lngOldPos = 1
lngOffset = 1
For lngPos = 1 To Len(strValue)
If InStr("+-", Mid(strValue, lngPos, 1)) > 0 Then
If lngPos > lngOldPos Then
oCell.Offset(0, lngOffset).Value = _
CDbl(Mid(strValue, lngOldPos, lngPos - lngOldPos))
lngOldPos = lngPos
lngOffset = lngOffset + 1
End If
End If
Next lngPos
oCell.Offset(0, lngOffset).Value = _
CDbl(Mid(strValue, lngOldPos))
End If
Next oCell

Set oCell = Nothing
End Sub

[Torquemada]

They are in one cell as =404.52-4233.55+17+15.22-357.75, and so on.

[Torquemada]

I copied this as-is and selected one cell to be parsed. Running it, all i got was the cell value as one number, next to the original.

[sdckapr]

Try changing the line:
strValue = oCell.Value

To:
strValue = Mid(oCell.Formula, 2)

Steve

[Torquemada]

That did the trick. Thanks. I will print this out and study it. That's a big help.