Results 1 to 3 of 3
  1. #1
    3 Star Lounger
    Join Date
    May 2003
    Location
    Mid-Cheshire, England
    Posts
    275
    Thanks
    1
    Thanked 3 Times in 3 Posts

    Show text box over image (PPT2000 SP3)

    I would be grateful for some help. I have a presentation of some 120 slides two-thirds of which are images the same size as the slide. Temporarily while completing the presentation I want to seperately display the slide number & the image number (they are different) over the images.

    In the footer I have implemented the include slide number facility but because of the above-mentioned full-size images is only seen on one-third of the slides. Is it possible to have the slide number appear over an image?

    I have inserted a text box on the Master Slide & set its order to the front but it does not appear over the images. Can a text box be displayed over an image? If so how?

  2. #2
    Silver Lounger
    Join Date
    Mar 2001
    Location
    Springfield, Ohio, USA
    Posts
    2,136
    Thanks
    0
    Thanked 1 Time in 1 Post

    Re: Show text box over image (PPT2000 SP3)

    Since your pictures cover the entire slide, you would have to create a text box on each page. Here is a macro to do just that. I have also attached a sample presentation with the code and instructions. You will have to save the attachment on your hard drive and open it in PowerPoint to run the macros. HTH --Sam
    <pre>Option Explicit

    Public Sub deletePageBoxes()
    Dim i As Long, s As Shape
    With ActivePresentation.Slides
    For i = 1 To .Count
    For Each s In .Item(i).Shapes
    If s.Name = "TextPage" Then s.Delete
    Next s
    Next i
    End With
    End Sub

    Public Sub createPageBoxes()
    Dim i As Long, j As Long, s As String
    deletePageBoxes
    With ActivePresentation.Slides
    j = 0
    For i = 1 To .Count
    If hasPicture(.Item(i)) Then
    j = j + 1
    s = "sld " & i & ", pic " & j
    Else
    s = "sld " & i
    End If
    With .Item(i).Shapes
    With .AddTextbox(msoTextOrientationHorizontal, 580#, 498#, 120#, 24#)
    .Name = "TextPage"
    .TextFrame.TextRange.Text = s
    .TextFrame.TextRange.Font.Size = 14
    .Fill.ForeColor.SchemeColor = ppBackground
    .Fill.Visible = msoTrue
    End With
    End With
    Next i
    End With
    End Sub

    Private Function hasPicture(sld As Slide) As Boolean
    Dim s As Shape
    For Each s In sld.Shapes
    If Left(s.Name, 7) = "Picture" Then
    hasPicture = True
    Exit Function
    End If
    Next s
    hasPicture = False
    End Function
    </pre>

    <font face="Comic Sans MS">Sam Barrett, CACI </font face=comic>
    <small>And the things that you have heard... commit these to faithful men who will be able to teach others also. 2 Timothy 2:2</small>

  3. #3
    3 Star Lounger
    Join Date
    May 2003
    Location
    Mid-Cheshire, England
    Posts
    275
    Thanks
    1
    Thanked 3 Times in 3 Posts

    Re: Show text box over image (PPT2000 SP3)

    Sam my thanks for your help - way beyond my expectations!

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •