Results 1 to 8 of 8
  1. #1
    2 Star Lounger
    Join Date
    Jul 2006
    Location
    Bangalore, India
    Posts
    180
    Thanks
    1
    Thanked 0 Times in 0 Posts

    Multiple If Conditions (Excel-2003)

    Hi Excel Experts,

    I need a formula that has quite a few combinations... I have created the fomula, however, I realised that I need to check for another condition.

    Can someone help me out on the same.
    D3 = 01-July-06
    E3 = 31-July-06
    F2 = Billable Month i.e = 20, 21 or 22
    F3 = NETWORKDAYS($D$3,$E$3,Holiday)= 21
    F4 = DAY(DATE(YEAR($D$3),MONTH($D$3)+1,0))= 31
    C6 = Date of Joining
    D6 = Amount
    E6 = Leaves Availed

    Formula in F6 = IF($A6="","", IF($F$2="", $F$4-$E6,IF($F$2<$F$3,$F$3-$E6,$F$2-$E6)))

    I need to add another condition here.

    i.e. if C6>D3, AND if F2="" then ((C6-E3)+1)-E6, ELSE NETWORKDAYS(C6,E3,Holiday)-E6

    Hope this clarifies. Attached is an excel sheet for your reference.

    Looking forward to a great formula on the same.

    Regards
    Baiju

  2. #2
    Plutonium Lounger
    Join Date
    Mar 2002
    Posts
    84,353
    Thanks
    0
    Thanked 29 Times in 29 Posts

    Re: Multiple If Conditions (Excel-2003)

    Hello Baiju,

    Welcome to Woody's Lounge!

    I don't see an attachment. Make sure that you specify the attachment just before clicking the Post It button. The maximum size for an attachment is 100 KB; you can zip your workbook if it is too large.

  3. #3
    Plutonium Lounger
    Join Date
    Mar 2002
    Posts
    84,353
    Thanks
    0
    Thanked 29 Times in 29 Posts

    Re: Multiple If Conditions (Excel-2003)

    Here is a guess without having seen the workbook:

    =IF(AND(C6>D3,F2=""),C6-E3+1,NETWORKDAYS(C6,E3,Holiday))-E6

  4. #4
    2 Star Lounger
    Join Date
    Jul 2006
    Location
    Bangalore, India
    Posts
    180
    Thanks
    1
    Thanked 0 Times in 0 Posts

    Re: Multiple If Conditions (Excel-2003)

    Hi Folks,

    I have attached an excel sheet, which will give you a clear picture.

    Regards
    Baiju

  5. #5
    Plutonium Lounger
    Join Date
    Mar 2002
    Posts
    84,353
    Thanks
    0
    Thanked 29 Times in 29 Posts

    Re: Multiple If Conditions (Excel-2003)

    Can you explain what exactly you mean by

    IF F2<F3, F3-E6,F2-E6
    IF C6>D3 then NETWORKDAYS(C6,E3,Holiday)-E6

  6. #6
    WS Lounge VIP sdckapr's Avatar
    Join Date
    Jul 2002
    Location
    Pittsburgh, Pennsylvania, USA
    Posts
    11,225
    Thanks
    14
    Thanked 342 Times in 335 Posts

    Re: Multiple If Conditions (Excel-2003)

    Perhaps this?
    =IF($F$2="",IF(C6>$D$3, ((C6-$E$3)+1)-E6,$F$4-E6),IF(C6>$D$3,NETWORKDAYS(C6,$E$3,Holiday)-E6,IF($F$2<$F$3,$F$3-E6,$F$2-E6)))

    Steve

  7. #7
    Plutonium Lounger
    Join Date
    Mar 2002
    Posts
    84,353
    Thanks
    0
    Thanked 29 Times in 29 Posts

    Re: Multiple If Conditions (Excel-2003)

    I think he also wants to test on A6="", as in the original formula in F6. How about

    =IF($A6="","",IF($F$2="",IF($C6>$D$3,$C6-$E$3+1,$F$4),IF($C6>$D$3,NETWORKDAYS($C6,$E$3, Holiday),MAX($F$2,$F$3)))-$E6)

    I used MAX instead of IF($F$2<$F$3,...) and moved the subtraction of E6 out of the inner IF.

  8. #8
    2 Star Lounger
    Join Date
    Jul 2006
    Location
    Bangalore, India
    Posts
    180
    Thanks
    1
    Thanked 0 Times in 0 Posts

    Re: Multiple If Conditions (Excel-2003)

    Hi Steve & Hans,

    I have got the intended result.. thanks for the great formula

    Regards
    Baiju

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •