Results 1 to 3 of 3
  1. #1
    Bronze Lounger
    Join Date
    Jan 2001
    Location
    Melbourne, Australia
    Posts
    1,294
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Track changes and cross references (Word 2002 XP SR3)

    A user has many large documents that required tracking. Currently the cross refereces to paragraphs are inserted as plain text and not cross reference fields. They have mentioned the reason is an issue with track changes and cross-refencing. Their concerned that if they insert cross-reference fields in a tracked document, whihc takes alot of work ,then the issue appears they have to undo it all.

    However I'm dont know of any issue, not to say there isnt any. I've had a look on the microsoft knowledge base but couldnt find anything relevant.

    Do you know of any?


    also do you know if there is an quicker/easier way to put in the cross referencing clauses other than

    going each time to the menu Insert, referencing, cross referencing and going down to find the actual clause etc.

    diana

  2. #2
    Bronze Lounger
    Join Date
    Jan 2001
    Location
    Melbourne, Australia
    Posts
    1,294
    Thanks
    0
    Thanked 0 Times in 0 Posts

    Re: Track changes and cross references (Word 2002 XP SR3)

    post #20301 has answered this question.

    many thanks

    diana

  3. #3
    Super Moderator
    Join Date
    May 2002
    Location
    Canberra, Australian Capital Territory, Australia
    Posts
    5,054
    Thanks
    2
    Thanked 417 Times in 346 Posts

    Re: Track changes and cross references (Word 2002 XP SR3)

    Hi Diana,

    <post#=20301>post 20301</post#> doesn't really help resolve the issue, but the following macro to accept all tracked changes involving fields should do the trick:

    <pre>Option Explicit

    Sub AcceptTrackedFields()
    Dim TrkStatus As Boolean ' Track Changes flag
    Dim oRange As Word.Range ' All Range objects - includes ranges in the body, headers, footers & shapes
    Dim TOC As TableOfContents ' Table of Contents Object
    Dim TOA As TableOfAuthorities ' Table of Authorities Object
    Dim TOF As TableOfFigures ' Table of Figures Object
    Dim Fld As Field ' Field Object
    ' Turn Off Screen Updating
    Application.ScreenUpdating = False
    With ActiveDocument
    ' Store current Track Changes status, then switch off
    TrkStatus = .TrackRevisions
    .TrackRevisions = False
    ' Loop through all range objects and accept tracked changes on fields
    For Each oRange In .StoryRanges
    Do
    For Each Fld In oRange.Fields
    Fld.Select
    Selection.Range.Revisions.AcceptAll
    Next
    Set oRange = oRange.NextStoryRange
    Loop Until oRange Is Nothing
    Next
    ' Loop through TOCs and update
    For Each TOC In .TablesOfContents
    TOC.Update
    Next
    ' Loop through TOAs and update
    For Each TOA In .TablesOfAuthorities
    TOA.Update
    Next
    ' Loop through TOFs and update
    For Each TOF In .TablesOfFigures
    TOF.Update
    Next
    ' Restore original Track Changes status
    .TrackRevisions = TrkStatus
    End With
    ' Restore Screen Updating
    Application.ScreenUpdating = True
    End Sub</pre>

    Cheers,

    Paul Edstein
    [MS MVP - Word]

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •